feat(pgctld): bump to b0d11a0

nix/packages/default.nix

@@ -74,7 +74,7 @@
           overlayfs-on-package = pkgs.callPackage ./overlayfs-on-package.nix { };
           packer = pkgs.callPackage ./packer.nix { inherit inputs; };
           pg-activity = inputs.nixpkgs.legacyPackages.${pkgs.stdenv.hostPlatform.system}.pg_activity;
-          pg-backrest = inputs.nixpkgs.legacyPackages.${pkgs.stdenv.hostPlatform.system}.pgbackrest;
+          pg-backrest = pkgs.callPackage ./pg-backrest.nix { };
           pgctld = pkgs.callPackage ./pgctld.nix {
             multigres-src = inputs.multigres;
           };

nix/packages/pg-backrest.nix

@@ -0,0 +1,30 @@
+{
+  fetchurl,
+  lib,
+  pgbackrest,
+  stdenv,
+  systemdLibs,
+}:
+pgbackrest.overrideAttrs (
+  finalAttrs: prevAttrs: {
+    version = "2.59.1";
+
+    # Deliberately the release tarball rather than fetchFromGitHub. As of 2.59.0
+    # upstream's .gitattributes marks /src/build as export-ignore, so the GitHub
+    # tag archive omits the code-generation tooling *and* the generated sources
+    # *and* the "dist" marker file — it simply cannot be built (meson fails with
+    # "File build/common/regExp.c does not exist").
+    src = fetchurl {
+      url = "https://github.com/pgbackrest/pgbackrest/releases/download/release/${finalAttrs.version}/pgbackrest-${finalAttrs.version}.tar.gz";
+      hash = "sha256-HNUir8M7j/hG74jFXcI4cXyciBek9sp8n2SIfenHQC0=";
+    };
+
+    # 2.59.0 adds an optional libsystemd dependency for systemd notify support.
+    # Nonexistent on darwin.
+    buildInputs =
+      (prevAttrs.buildInputs or [ ]) ++ lib.optional stdenv.hostPlatform.isLinux systemdLibs;
+    mesonFlags = (prevAttrs.mesonFlags or [ ]) ++ [
+      (lib.mesonEnable "libsystemd" stdenv.hostPlatform.isLinux)
+    ];
+  }
+)

nix/packages/pgctld.nix

@@ -17,7 +17,7 @@ buildGo126Module {
   '';
   # Tests require a running PostgreSQL instance (integration tests); skip in sandbox.
   doCheck = false;
-  vendorHash = "sha256-oRP1ZvRmE8eqYmJIuZSad3/BVicmAFkBJ4qSaiD6F0E=";
+  vendorHash = "sha256-J8Yjnwkwmk6kL0qsyGUgak9O26daYzly/1GwEwYn0IU=";
 
   meta = {
     description = "PostgreSQL control daemon for Multigres cluster lifecycle management";