start-node.cmd

@echo off
setlocal enabledelayedexpansion

taskkill /F /FI "WINDOWTITLE eq Agnes2Opencode - Node.js Mode" /T >nul 2>&1
timeout /t 1 /nobreak >nul

cd /d "%~dp0"

:: Detect port from config first
set "PORT=8082"
set "CONFIG_FILE=%~dp0.config\config.json"
if exist "%CONFIG_FILE%" (
    for /f "usebackq delims=" %%a in (`powershell -NoProfile -Command "$c=Get-Content '%CONFIG_FILE%' -Raw ^| ConvertFrom-Json; $l=$c.LISTEN_ADDR; if($l -match ':(?<p>\d+)$'){Write-Output $matches['p']}else{Write-Output '8082'}"`) do set "PORT=%%a"
)

title Agnes2Opencode - Node.js Mode

echo ==================================================
echo  Agnes2Opencode - Node.js Mode
echo  Enforces Node.js (ignores Bun)
echo ==================================================
echo.

echo [1/4] Cleaning up...
for /f "tokens=5" %%a in ('netstat -ano ^| findstr ":%PORT% " ^| findstr "LISTENING"') do (
    taskkill /PID %%a /F >nul 2>&1
)
timeout /t 1 /nobreak >nul

echo [2/4] Installing dependencies...
call npm i
if exist "%~dp0package-lock.json" del /q "%~dp0package-lock.json"
title Agnes2Opencode - Node.js Mode
echo.

echo [3/4] Detecting Node.js...
where node >nul 2>&1
if %ERRORLEVEL% neq 0 goto :no_runtime

echo [INFO] Runtime: Node.js

echo [4/4] Starting proxy...
echo.
echo ==================================================
echo  Proxy: http://localhost:%PORT%
echo  Dashboard: http://localhost:%PORT%/dashboard
echo ==================================================
echo.

set PROXY_RUNTIME=node
node proxy.js

set EXIT_CODE=%ERRORLEVEL%
if %EXIT_CODE% equ 0 goto :done
if %EXIT_CODE% equ -1073741819 goto :done
echo.
echo [ERROR] Proxy exited with code %EXIT_CODE%
pause
goto :done

:no_runtime
echo [ERROR] Node.js not found in PATH.
echo        Install Node: https://nodejs.org
pause

:done
echo.
echo Proxy stopped.
pause